Gerador de orçamentos

Módulo1 (Código)

Option Explicit

' Gera o PDF do orçamento na mesma pasta da planilha e registra no histórico.
Public Sub GerarPDF()
    Dim orc As Worksheet
    Dim caminho As String

    Set orc = ThisWorkbook.Worksheets("Orçamento")
    If Trim$(orc.Range("C4").Value) = "" Then
        MsgBox "Escolha o cliente antes de gerar o PDF.", vbExclamation
        Exit Sub
    End If
    If Application.WorksheetFunction.CountA(orc.Range("B7:B14")) = 0 Then
        MsgBox "Inclua ao menos um item no orçamento.", vbExclamation
        Exit Sub
    End If

    caminho = ThisWorkbook.Path & Application.PathSeparator & _
              "Orcamento_" & orc.Range("G2").Value & ".pdf"

    orc.ExportAsFixedFormat Type:=xlTypePDF, Filename:=caminho, _
        Quality:=xlQualityStandard, IgnorePrintAreas:=False, _
        OpenAfterPublish:=False

    SalvarHistorico caminho
    MsgBox "PDF salvo em:" & vbCrLf & caminho, vbInformation
End Sub

' Copia número, data, cliente e total para a aba Histórico e avança a numeração.
Private Sub SalvarHistorico(ByVal caminho As String)
    Dim orc As Worksheet, hist As Worksheet
    Dim linha As Long

    Set orc = ThisWorkbook.Worksheets("Orçamento")
    Set hist = ThisWorkbook.Worksheets("Histórico")
    linha = hist.Cells(hist.Rows.Count, "A").End(xlUp).Row + 1

    hist.Cells(linha, "A").Value = orc.Range("G2").Value
    hist.Cells(linha, "B").Value = Date
    hist.Cells(linha, "C").Value = orc.Range("C4").Value
    hist.Cells(linha, "D").Value = orc.Range("G18").Value
    hist.Hyperlinks.Add Anchor:=hist.Cells(linha, "E"), _
        Address:=caminho, TextToDisplay:="Abrir PDF"

    orc.Range("G2").Value = orc.Range("G2").Value + 1
End Sub

' Limpa os itens e o cliente para começar um orçamento novo.
Public Sub NovoOrcamento()
    With ThisWorkbook.Worksheets("Orçamento")
        .Range("C4").ClearContents
        .Range("B7:B14,D7:D14").ClearContents
        .Range("C4").Select
    End With
End Sub